AtEndOfLine 属性

描述

只读属性，在 TextStream 文件中，如果文件指针正好在行尾标记的前面，那么该属性值返回 True；否则返回 False。

语法

object.AtEndOfLine

object 总是一个 TextStream 对象的名称。

说明

AtEndOfLine 属性仅应用于已打开供读取的 TextStream 文件；否则就会出错。

下面的代码举例说明了 AtEndOfLine 属性的用法：

Dim fs, a, retstring
Set fs = CreateObject("Scripting.FileSystemObject")
Set a = fs.OpenTextFile("c:\testfile.txt", ForReading, False)
Do While a.AtEndOfLine <> True
    retstring = a.Read(1)
    ...
Loop
a.Close

AtEndOfStream 属性

描述

只读属性，如果文件指针在 TextStream 文件末尾，则该属性值返回 True；否则返回 False。

语法

object.AtEndOfStream

object 总是一个 TextStream 对象的名称。

说明

AtEndOfStream 属性仅应用于已打开供读取的 TextStream 文件；否则就会出错。

下面的代码举例说明了 AtEndOfStream 属性的用法：

Dim fs, a, retstring
Set fs = CreateObject("Scripting.FileSystemObject")
Set a = fs.OpenTextFile("c:\testfile.txt", ForReading, False)
Do While a.AtEndOfStream <> True
    retstring = a.ReadLine
    ...
Loop
a.Close

Attributes 属性

描述

设置或者返回文件或文件夹的属性。读/写或只读，取决于属性。

语法

object.Attributes [= newattributes]

Attributes 属性有下列几个部分：

设置

newattributes 参数可以是具有下列值中的任意一个或任意的逻辑组合：

说明

下面的代码用一个文件举例说明了 Attributes 属性的用法：

Sub SetClearArchiveBit(filespec)
    Dim fs, f, r
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(fs.GetFileName(filespec))
    If f.attributes and 32 Then
        r = MsgBox("The Archive bit is set, do you want to clear it?", vbYesNo, "Set/Clear Archive Bit")
        If r = vbYes Then
            f.attributes = f.attributes - 32
            MsgBox "Archive bit is cleared."
        Else
            MsgBox "Archive bit remains set."
        End If
    Else
        r = MsgBox("The Archive bit is not set. Do you want to set it?", vbYesNo, "Set/Clear Archive Bit")
        If r = vbYes Then
            f.attributes = f.attributes + 32
            MsgBox "Archive bit is set."
        Else
            MsgBox "Archive bit remains clear."
        End If
    End If
End Sub

AvailableSpace 属性

描述

返回在指定的驱动器或网络共享上的用户可用空间容量。

语法

object.AvailableSpace

object 总是一个 Drive 对象。

说明

一般来说，AvailableSpace 属性的返回值与 FreeSpace 属性的返回值是相同的。对于支持限额的计算机系统来说，两个值之间可能会有所不同。

下面的代码举例说明了 AvailableSpace 属性的用法：

Sub ShowAvailableSpace(drvPath)
    Dim fs, d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(drvPath))
    s = "Drive " & UCase(drvPath) & " - "
    s = s & d.VolumeName  & vbCrLf
    s = s & "Available Space: " & FormatNumber(d.AvailableSpace/1024, 0)
    s = s & " Kbytes"
    MsgBox s
End Sub

Calendar 属性

返回或设置一个值，指出工程中所使用日历的类型。

可以为 Calendar使用下列设置之一:

说明

可以程序化地只设置Calendar 属性。例如，要使用Hijri 日历，使用：

Calendar = vbCalHijri

Column 属性

描述

只读属性，返回 TextStream 文件中当前字符位置的列号。

语法

object.Column

object 总是一个 TextStream 对象的名称。

说明

在写了一个新行字符后，但在写任何其他字符之前，Column 的值是 1。

CompareMode 属性

描述

设置或返回某个 Dictionary 对象中的比较字符串关键字的比较模式。

语法

object.CompareMode[ = compare]

CompareMode 属性具有下列部分：

设置

compare 参数可以具有下列值：

说明

如果试图对已经包含数据的 Dictionary 对象的比较模式进行更改的话，就会出错。

CompareMode 属性所用的参数值与 StrComp 函数所用的 compare 参数相同。可以用大于 2 的值表示使用特定 Locale IDs (LCID) 的比较。

Count 属性

描述

返回集合或 Dictionary 对象中的条目数。只读。

语法

object.Count

object 总是“应用于”列表中某一项的名称。

说明

下面的代码举例说明了 Count 属性的使用方法：

Dim a, d, i             '创建一些变量
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '添加一些关键字和条目。
d.Add "b", "Belgrade"
d.Add "c", "Cairo"
a = d.Keys              '获得关键字
For i = 0 To d.Count -1 '遍及数组
    Print a(i)          '打印关键字
Next
...

DateCreated 属性

描述

返回指定文件或文件夹的创建日期和时间。只读。

语法

object.DateCreated

object 总是一个 file 或Folder对象。

说明

下面的代码用一个文件举例说明了 DateCreated 属性的用法：

Sub ShowFileInfo(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = "Created: " & f.DateCreated
    MsgBox s
End Sub

DateLastAccessed 属性

描述

返回最后一次访问指定文件或文件夹的日期和时间。只读。

语法

object.DateLastAccessed

object 总是一个 file 或 Folder 对象。

说明

下面的代码用一个文件举例说明了 DateLastAccessed 属性的用法：

Sub ShowFileAccessInfo(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = UCase(filespec) & vbCrLf
    s = s & "Created: " & f.DateCreated & vbCrLf
    s = s & "Last Accessed: " & f.DateLastAccessed & vbCrLf
    s = s & "Last Modified: " & f.DateLastModified
    MsgBox s, 0, "File Access Info"
End Sub

重点   这种方法由其下一级操作系统决定其行为。如果操作系统不支持提供时间信息，则没有返回信息。

DateLastModified 属性

描述

返回最后一次修改指定文件或文件夹的日期和时间。只读。

语法

object.DateLastModified

object 总是一个 file 或 Folder 对象。

说明

下面的代码用一个文件举例说明了 DateLastModified 属性的用法：

Sub ShowFileAccessInfo(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = UCase(filespec) & vbCrLf
    s = s & "Created: " & f.DateCreated & vbCrLf
    s = s & "Last Accessed: " & f.DateLastAccessed & vbCrLf
    s = s & "Last Modified: " & f.DateLastModified
    MsgBox s, 0, "File Access Info"
End Sub

Description 属性

返回或设置一个字符串表达式，包含与对象相关联的描述性字符串。可读/可写。

对于 Err 对象，返回或设置与错误相关联的描述性字符串。

说明

Description 属性设置对错误进行简短描述。当无法处理或不想处理错误的时候，可以使用这个属性提醒用户。在生成用户自定义的错误时，将有关此错误的一个简短陈述指定给 Description 属性。如果 Description 未填入数据，而且 Number 的值与 Visual Basic 运行时错误一致，那么在生成错误时，将 Error 函数返回的字符串放置在 Description 中。

Drive 属性

描述

返回指定文件或文件夹所在的驱动器符号。只读。

语法

object.Drive

object 总是一个 File 或 Folder 对象。

说明

下面的代码举例说明了 Drive 属性的用法：

Sub ShowFileAccessInfo(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = f.Name & " on Drive " & UCase(f.Drive) & vbCrLf
    s = s & "Created: " & f.DateCreated & vbCrLf
    s = s & "Last Accessed: " & f.DateLastAccessed & vbCrLf
    s = s & "Last Modified: " & f.DateLastModified
    MsgBox s, 0, "File Access Info"
End Sub

DriveLetter 属性

描述

返回某个物理本地驱动器或网络共享的驱动器字母。只读。

语法

object.DriveLetter

object 总是一个 Drive 对象。

说明

如果指定的驱动器没有同某个驱动器字母关联起来，例如，未被映射到一个驱动器字母的网络共享，则 DriveLetter 属性返回一个 0 字节长度的字符串 ("")。

下面的代码举例说明了 DriveLetter 属性的用法：

Sub ShowDriveLetter(drvPath)
    Dim fs, d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(drvPath))
    s = "Drive " & d.DriveLetter & ": - "
    s = s & d.VolumeName  & vbCrLf
    s = s & "Free Space: " & FormatNumber(d.FreeSpace/1024, 0)
    s = s & " Kbytes"
    MsgBox s
End Sub

Drives 属性

描述

返回包含本地机器上所有可用 Drive 对象的 Drives 集合。

语法

object.Drives

object 总是一个 FileSystemObject。

说明

对于可删除媒体驱动器来说，不需要插入媒体，就可使其出现在 Drives 集合中。

可以用 For Each...Next 结构遍及 Drives 集合中的成员，如下面的代码所示：

Sub ShowDriveList
    Dim fs, d, dc, s, n
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set dc = fs.Drives
    For Each d in dc
        s = s & d.DriveLetter & " - "
        If d.DriveType = 3 Then
            n = d.ShareName
        Else
            n = d.VolumeName
        End If
        s = s & n & vbCrLf
    Next
    MsgBox s
End Sub

DriveType 属性

描述

返回一个值，表示指定驱动器的类型。

语法

object.DriveType

object 总是一个 Drive 对象。

说明

下面的代码举例说明了 DriveType 属性的用法：

Sub ShowDriveType(drvpath)
    Dim fs, d, s, t
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(drvpath)
    Select Case d.DriveType
        Case 0: t = "Unknown"
        Case 1: t = "Removable"
        Case 2: t = "Fixed"
        Case 3: t = "Network"
        Case 4: t = "CD-ROM"
        Case 5: t = "RAM Disk"
    End Select
    s = "Drive " & d.DriveLetter & ": - " & t
    MsgBox s
End Sub

Files 属性

描述

返回由所有 File 对象组成的 Files 集合，这些 File 对象包含在指定的文件夹中──包括设置了隐藏和系统文件属性的那些文件。

语法

object.Files

object 总是一个 Folder 对象。

说明

下面的代码举例说明了 Files 属性的用法：

Sub ShowFileList(folderspec)
    Dim fs, f, f1, fc, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(folderspec)
    Set fc = f.Files
    For Each f1 in fc
        s = s & f1.name
        s = s &  vbCrLf
    Next
    MsgBox s
End Sub

FileSystem 属性

描述

返回指定驱动器所使用的文件系统类型。

语法

object.FileSystem

object 总是一个 Drive 对象。

说明

可以得到的返回类型包括 FAT、NTFS、以及 CDFS。

下面的代码举例说明了 FileSystem 属性的用法：

Sub ShowFileSystemType
    Dim fs,d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive("e:")
    s = d.FileSystem
    MsgBox s
End Sub

FreeSpace 属性

描述

返回指定驱动器上或网络共享的用户可用磁盘剩余空间容量。只读。

语法

object.FreeSpace

object 总是一个 Drive 对象。

说明

一般来说，FreeSpace 属性的返回值和 AvailableSpace 属性的返回值是相同的。对于支持限额的计算机系统来说，二者之间可能有所不同。

下面的代码举例说明了 FreeSpace 属性的用法：

Sub ShowFreeSpace(drvPath)
    Dim fs, d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(drvPath))
    s = "Drive " & UCase(drvPath) & " - "
    s = s & d.VolumeName  & vbCrLf
    s = s & "Free Space: " & FormatNumber(d.FreeSpace/1024, 0)
    s = s & " Kbytes"
    MsgBox s
End Sub

HelpContext 属性

返回或设置一个字符串表达式，包含 Microsoft Windows 帮助文件中的主题的上下文 ID。可读 / 可写。

说明

HelpContext 属性被用来自动显示 HelpFile 属性中指定的帮助主题。如果 HelpFile 和 HelpContext 都是空的，则检查 Number 的值。如果 Number 的值与 Visual Basic 运行时错误一致，则对此错误使用 Visual Basic 帮助上下文 ID。如果 Number 的值与 Visual Basic 错误不一致，则在屏幕上显示 Visual Basic 帮助文件的内容。

注意 应该在应用程序中写入一些例程来处理常见错误。当使用对象编程时，可以用该对象的帮助文件来提高处理错误的质量，而如果错误无法补救，则要为用户显示一段有意义的消息。

HelpFile 属性

返回或设置一个字符串表达式，表示帮助文件的完整限定路径。可读/可写。

说明

如果 HelpFile 中指定了帮助文件，则当用户在错误消息对话框中按下 Help 按钮（或)）时，帮助文件被自动调用。如果 HelpContext 属性包含被指定文件的有效的上下文 ID，则自动显示那一主题。如果未指定 HelpFile，则显示 Visual Basic 帮助文件。

注意 应该在应用程序中写入一些例程来处理常见错误。当使用对象编程时，可以用该对象的帮助文件来提高处理错误的质量，而如果错误无法补救，则要为用户显示一段有意义的消息。

IsReady 属性

描述

如果指定的驱动器已准备好，返回 True；否则返回 False。

语法

object.IsReady

object 总是一个 Drive 对象。

说明

对于可删除媒体驱动器和 CD-ROM 驱动器来说，仅当插入了适当的媒体，并已准备好供访问时，IsReady 才返回 True。

下面的代码举例说明了 IsReady 属性的用法：

Sub ShowDriveInfo(drvpath)
    Dim fs, d, s, t
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(drvpath)
    Select Case d.DriveType
        Case 0: t = "Unknown"
        Case 1: t = "Removable"
        Case 2: t = "Fixed"
        Case 3: t = "Network"
        Case 4: t = "CD-ROM"
        Case 5: t = "RAM Disk"
    End Select
    s = "Drive " & d.DriveLetter & ": - " & t
    If d.IsReady Then
        s = s & vbCrLf & "Drive is Ready."
    Else
        s = s & vbCrLf & "Drive is not Ready."
    End If
    MsgBox s
End Sub

IsRootFolder 属性

描述

如果指定的文件夹是根文件夹，则返回 True；否则返回 False。

语法

object.IsRootFolder

object 总是一个 Folder 对象。

说明

下面的代码举例说明了 IsRootFolder 属性的用法：

Dim fs
Set fs = CreateObject("Scripting.FileSystemObject")
Sub DisplayLevelDepth(pathspec)
    Dim f, n
    Set f = fs.GetFolder(pathspec)
    If f.IsRootFolder Then
        MsgBox "The specified folder is the root folder."
    Else
        Do Until f.IsRootFolder
            Set f = f.ParentFolder
            n = n + 1
        Loop
        MsgBox "The specified folder is nested " & n & " levels deep."
    End If
End Sub

Item 属性

描述

对 Dictionary 对象中指定的 Key，设置或返回一个 Item 。对于集合来说，基于指定的 Key ，返回一个 Item 。读/写属性。

语法

object.Item(key) [= newitem]

Item 属性具有下列部分：

说明

如果在改变某个 item 时，没有找到 key，则用指定的newitem创建一个新的 key 。如果在试图返回某个已存在条目时，没有找到 key，则创建一个新 key，且其相应的条目为空。

Key 属性

描述

在一个 Dictionary 对象中设置一个 key。

语法

object.Key(key) = newkey

Key 属性具有下列部分：

说明

如果在更改某个 key 时，没有找到 key，则会出现运行时错误。

LastDLLError 属性

返回因调用动态链接库 (DLL) 而产生的系统错误号。只读。

说明

LastDLLError 属性只适用于由 Visual Basic 代码进行的 DLL 调用。在调用时，被调用的函数通常返回一个表明成功还是失败的代码，同时对 LastDLLError 属性填充数据。请检查 DLL 函数的文档，确定返回值，表明是成功还是失败。只要返回失败代码，Visual Basic 的应用程序就应立即检查 LastDLLError 属性。在设置 LastDLLError 属性时不会有任何例外。

Line 属性

描述

只读属性，返回一个 TextStream 文件中的当前行号。

语法

object.Line

object 总是一个 TextStream 对象的名字。

说明

文件初次打开后，在写任何东西之前，Line 的值为 1。

Name 属性

描述

设置或返回指定文件或文件夹名。读/写属性。

语法

object.Name [= newname]

Name 属性有下列几部分：

说明

下面的代码举例说明了 Name 属性的用法：

Sub ShowFileAccessInfo(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = f.Name & " on Drive " & UCase(f.Drive) & vbCrLf
    s = s & "Created: " & f.DateCreated & vbCrLf
    s = s & "Last Accessed: " & f.DateLastAccessed & vbCrLf
    s = s & "Last Modified: " & f.DateLastModified
    MsgBox s, 0, "File Access Info"
End Sub

Number 属性

返回或设置表示错误的数值。Number 是 Err 对象的缺省属性。可读/可写。

说明

从对象返回用户自定义的错误时，把被选作错误代码的数与 vbObjectError 常数相加，并由此设置 Err.Number。例如，用下列代码返回作为错误代码的数字 1051：

Err.Raise Number := vbObjectError + 1051, Source:= SomeClass

ParentFolder 属性

描述

返回指定文件或文件夹的父文件夹对象。只读。

语法

object.ParentFolder

object 总是一个 File 或 Folder 对象。

说明

下面的代码用一个文件举例说明了 ParentFolder 属性的用法：

Sub ShowFileAccessInfo(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = UCase(f.Name) & " in " & UCase(f.ParentFolder) & vbCrLf
    s = s & "Created: " & f.DateCreated & vbCrLf
    s = s & "Last Accessed: " & f.DateLastAccessed & vbCrLf
    s = s & "Last Modified: " & f.DateLastModified
    MsgBox s, 0, "File Access Info"
End Sub

Path 属性

描述

返回指定文件、文件夹、或驱动器的路径。

语法

object.Path

object 总是一个 File、Folder、或 Drive 对象。

说明

对于驱动器字母来说，不包括根驱动器。例如，C 驱动器的路径是 C:，而不是 C:\。

下面的代码用一个 File 对象举例说明了 Path 属性的用法：

Sub ShowFileAccessInfo(filespec)
    Dim fs, d, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = UCase(f.Path) & vbCrLf
    s = s & "Created: " & f.DateCreated & vbCrLf
    s = s & "Last Accessed: " & f.DateLastAccessed & vbCrLf
    s = s & "Last Modified: " & f.DateLastModified
    MsgBox s, 0, "File Access Info"
End Sub

RootFolder 属性

描述

返回一个 Folder 对象，该对象表示一个指定驱动器的根文件夹。只读属性。

语法

object.RootFolder

object 总是一个 Drive 对象。

说明

驱动器上所包含的所有文件和文件夹都可以使用返回的 Folder 对象进行访问。

SerialNumber 属性

描述

返回用于唯一标识磁盘卷标的十进制序列号。

语法

object.SerialNumber

object 总是一个 Drive 对象。

说明

可以使用 SerialNumber 属性确保正确的磁盘已插入到某个带有可删除媒体的驱动器中。

下面的代码举例说明了 SerialNumber 属性的用法：

Sub ShowDriveInfo(drvpath)
    Dim fs, d, s, t
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(fs.GetAbsolutePathName(drvpath)))
    Select Case d.DriveType
        Case 0: t = "Unknown"
        Case 1: t = "Removable"
        Case 2: t = "Fixed"
        Case 3: t = "Network"
        Case 4: t = "CD-ROM"
        Case 5: t = "RAM Disk"
    End Select
    s = "Drive " & d.DriveLetter & ": - " & t
    s = s & vbCrLf & "SN: " & d.SerialNumber
    MsgBox s
End Sub

ShareName 属性

描述

返回指定驱动器的网络共享名。

语法

object.ShareName

object 总是一个 Drive 对象。

说明

如果 object 不是一个网络驱动器，则 ShareName 属性返回一个 0 字节长度的字符串 ("")。

下面的代码举例说明了 ShareName 属性的用法：

Sub ShowDriveInfo(drvpath)
    Dim fs, d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(fs.GetAbsolutePathName(drvpath)))
    s = "Drive " & d.DriveLetter & ": - " & d.ShareName
    MsgBox s
End Sub

ShortName 属性

描述

返回需要较早的 8.3 命名约定的程序所使用的短名字。

语法

object.ShortName

object 总是一个 File 或 Folder 对象。

说明

下面的代码用一个 File 对象举例说明了 ShortName 属性的用法：

Sub ShowShortName(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = "The short name for " & "" & UCase(f.Name)
    s = s & "" & vbCrLf
    s = s & "is: " & "" & f.ShortName & ""
    MsgBox s, 0, "Short Name Info"
End Sub

ShortPath 属性

描述

返回需要较早的 8.3 文件命名约定的程序所使用的短路径。

语法

object.ShortPath

object 总是一个 File 或 Folder 对象。

说明

下面的代码用一个 File 对象举例说明了 ShortName 属性的用法：

Sub ShowShortPath(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFile(filespec)
    s = "The short path for " & "" & UCase(f.Name)
    s = s & "" & vbCrLf
    s = s & "is: " & "" & f.ShortPath & ""
    MsgBox s, 0, "Short Path Info"
End Sub

Size 属性

描述

对于文件来说，返回以字节为单位的指定文件大小。对于文件夹来说，返回以字节为单位的包含在文件夹中所有文件和子文件夹的大小。

语法

object.Size

object 总是一个 File 或 Folder 对象。

说明

下面的代码用一个 Folder 对象举例说明了 Size 属性的用法：

Sub ShowFolderSize(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(filespec)
    s = UCase(f.Name) & " uses " & f.size & " bytes."
    MsgBox s, 0, "Folder Size Info"
End Sub

Source 属性

返回或设置一个字符串表达式，指明最初生成错误的对象或应用程序的名称。可读 / 可写。

说明

Source 属性是字符串表达式，指定生成错误的对象；此表达式通常是这个对象的类名或程序设计的 ID。在程序代码无法处理被访问对象产生的错误时，请使用 Source 提供消息。例如，如果访问 Microsoft Excel 时生成了一个“除以零”的错误，则 Microsoft Excel 将 Err.Number 设置成代表此错误的错误代码，并将 Source 设置成 Excel.Application。

在错误生成时，Source 就是应用程序的程序设计 ID。对于类模块，Source 应该包含一个具有 project.class 窗体的名称。当代码中出现不可预料的错误时，Source 属性会自动填上数据。对于标准模块中的错误，Source 含有工程名称。对于类模块中的错误，Source 包含具有 project.class 窗体的名称。

SubFolders 属性

描述

返回包含所有文件夹的一个 Folders 集合，这些文件夹包含在某个特定的文件夹中，包括设置了隐藏和系统文件属性的那些文件夹。

语法

object.SubFolders

object 总是一个 Folder 对象。

说明

下面的代码举例说明了 SubFolders 属性的用法：

Sub ShowFolderList(folderspec)
    Dim fs, f, f1, s, sf
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(folderspec)
    Set sf = f.SubFolders
    For Each f1 in sf
        s = s & f1.name
        s = s &  vbCrLf
    Next
    MsgBox s
End Sub

TotalSize 属性

描述

以字节为单位，返回驱动器或网络共享的总空间大小。

语法

object.TotalSize

object 总是一个 Drive 对象。

说明

下面的代码举例说明了 TotalSize 属性的用法：

Sub ShowSpaceInfo(drvpath)
    Dim fs, d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(fs.GetAbsolutePathName(drvpath)))
    s = "Drive " & d.DriveLetter & ":"
    s = s & vbCrLf
    s = s & "Total Size: " & FormatNumber(d.TotalSize/1024, 0) & " Kbytes"
    s = s & vbCrLf
    s = s & "Available: " & FormatNumber(d.AvailableSpace/1024, 0) & " Kbytes"
    MsgBox s
End Sub

Type 属性

描述

返回关于某个文件或文件夹类型的信息。例如，对于以.TXT 结尾的文件来说，返回 "Text Document"。

语法

object.Type

object 总是一个 File 或 Folder 对象。

说明

下面的代码举例说明了返回某个文件夹类型的 Type 属性的用法。在这个示例中，试图将 Recycle Bin 的路径或其他唯一的文件夹提供给过程。

Sub ShowFileSize(filespec)
    Dim fs, f, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(filespec)
    s = UCase(f.Name) & " is a " & f.Type
    MsgBox s, 0, "File Size Info"
End Sub

VolumeName 属性

描述

设置或返回指定驱动器的卷标名。读/写属性。

语法

object.VolumeName [= newname]

VolumeName 属性有下列几部分：

说明

下面的代码举例说明了 VolumeName 属性的用法：

Sub ShowVolumeInfo(drvpath)
    Dim fs, d, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set d = fs.GetDrive(fs.GetDriveName(fs.GetAbsolutePathName(drvpath)))
    s = "Drive " & d.DriveLetter & ": - " & d.VolumeName
    MsgBox s
End Sub